Выборка данных из периодического регистра сведений на разные даты

ВЫБРАТЬ
 ПродажиОбороты.Период КАК ДатаПродажи,
 ПродажиОбороты.Контрагент,
 ПродажиОбороты.Номенклатура,
 ПродажиОбороты.КоличествоОборот,
 ПродажиОбороты.СуммаОборот
ПОМЕСТИТЬ Продажи
ИЗ
 РегистрНакопления.Продажи.Обороты(, , День, ) КАК ПродажиОбороты
;
// Собираем Все продажи товара
/////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
 Продажи.ДатаПродажи,
 Продажи.Контрагент,
 Продажи.Номенклатура,
 Продажи.КоличествоОборот,
 Продажи.СуммаОборот,
 ЦеныТоваров.ВидЦены,
 МАКСИМУМ(ЦеныТоваров.Период) КАК ДатаЦены
ПОМЕСТИТЬ ПериодЦены
ИЗ
 Продажи КАК Продажи
  ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныТоваров КАК ЦеныТоваров
  ПО Продажи.Номенклатура = ЦеныТоваров.Номенклатура
   И Продажи.ДатаПродажи >= ЦеныТоваров.Период
   И (ЦеныТоваров.ВидЦены = &ВидЦены)

СГРУППИРОВАТЬ ПО
 Продажи.ДатаПродажи,
 Продажи.Контрагент,
 Продажи.Номенклатура,
 ЦеныТоваров.ВидЦены,
 Продажи.КоличествоОборот,
 Продажи.СуммаОборот
;
// Получаем максимальные к датам продаж даты изменения цен
/////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
 ПериодЦены.ДатаПродажи,
 ПериодЦены.Контрагент,
 ПериодЦены.Номенклатура,
 ПериодЦены.КоличествоОборот,
 ПериодЦены.СуммаОборот,
 ПериодЦены.ВидЦены,
 ПериодЦены.ДатаЦены,
 ЦеныТоваров.Цена
ИЗ
 ПериодЦены КАК ПериодЦены
  ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныТоваров КАК ЦеныТоваров
  ПО ПериодЦены.Номенклатура = ЦеныТоваров.Номенклатура
   И ПериодЦены.ДатаЦены = ЦеныТоваров.Период
   И ПериодЦены.ВидЦены = ЦеныТоваров.ВидЦены